Subject:
|
Re: Muzzle flash in POV-Ray?
|
Newsgroups:
|
lugnet.cad.ray
|
Date:
|
Tue, 7 May 2002 21:08:42 GMT
|
Viewed:
|
722 times
|
| |
|
|
In lugnet.cad.ray, Dave Schuler writes:
> In lugnet.cad.ray, Jeremy H. Sproat writes:
>
> > I have two quickies: the quick way and the long way. (Note that both
> > examples were written towards POVRay version 3.1g...)
> **snip**
>
> Whoa! That'll keep me busy for a while... Thanks for the detailed
> help--I'm sure this will more than meet my meager needs. After I've messed
> around with it over the next few nights I'll try to post something.
My proxy server is really flaky right now, leaving me able to read
everything in this thread *except* for Jeremy's example post. So I haven't
seen his example yet, but here's a hacked-up snippet from a current project.
// Code starts here //
#macro EffectExhaustFlame (FlameScale,FlameColor)
union {
light_source {<0,5,0> color rgb FlameColor*FlameScale}
difference {
sphere { <0,0,0> 1
matrix <20,0,0,0,30,0,0,0,20,0,18,0> }
cone { <0,0,0>, 20 <0,-15,0> 20 }
hollow
pigment {rgbf .2}
interior{media{emission rgb FlameColor*.5}}
}
matrix <1,0,0,0,FlameScale,0,0,0,1,0,0,0>
}
#end
background { color rgb <0,0,0>}
camera {
location <200,500,200>
sky -y
right -4/3*x
look_at <0,0,0>
angle 67.3801
}
#declare FlameColorYellowish=color rgb <1,.7,.4>
object{EffectExhaustFlame (5,FlameColorYellowish)}
object{EffectExhaustFlame (5,FlameColorYellowish*3) matrix
<0,.5,0,.5,0,0,0,0,.5,20,0,0>}
object{EffectExhaustFlame (5,FlameColorYellowish*3) matrix
<0,.5,0,-.5,0,0,0,0,.5,-20,0,0>}
object{EffectExhaustFlame (5,FlameColorYellowish*3) matrix
<.5,0,0,0,0,.5,0,.5,0,0,0,20>}
object{EffectExhaustFlame (5,FlameColorYellowish*3) matrix
<.5,0,0,0,0,-.5,0,.5,0,0,0,-20>}
/* Code ends here
The macro sets up a decent looking flame, and the objects at the end are
separate instances of that flame. There's a big one in the center, and four
angled flames surrounding it such as you might see coming out the muzzle vents.
Note that FlameScale controls the length to width ratio of the flame.
Higher values create longer flames. Note also the multiplier on the color
for the smaller flames. That makes up for the fact that media gets dimmer
when you look through smaller amounts- without this multiplier, the side
flames would be very dim. If you scale the flame way up, you'll have to
scale the color down so that you don't get a solid white mess.
--
Tony Hafner
www.hafhead.com */
|
|
Message has 1 Reply:
 | | Re: Muzzle flash in POV-Ray?
|
| (...) Okay, this machine still can't find that page, but I've got another machine pointing to another bank of proxy servers and I was able to see it there. Wow- Jeremy has much better examples. I may use some of those techniques for my flames. I'll (...) (22 years ago, 7-May-02, to lugnet.cad.ray)
|
Message is in Reply To:
| | Re: Muzzle flash in POV-Ray?
|
| (...) **snip** Whoa! That'll keep me busy for a while... Thanks for the detailed help--I'm sure this will more than meet my meager needs. After I've messed around with it over the next few nights I'll try to post something. Thanks again, Dave! (22 years ago, 7-May-02, to lugnet.cad.ray)
|
8 Messages in This Thread:
  
- Entire Thread on One Page:
- Nested:
All | Brief | Compact | Dots
Linear:
All | Brief | Compact
This Message and its Replies on One Page:
- Nested:
All | Brief | Compact | Dots
Linear:
All | Brief | Compact
|
|
|
|
