Subject:
|
Re: water floor
|
Newsgroups:
|
lugnet.cad.ray
|
Date:
|
Sat, 8 Mar 2003 12:29:21 GMT
|
Viewed:
|
1137 times
|
| |
|
|
"Thomas Burger" <tburger321@aol.com> skrev i meddelandet
news:HBF1z9.9s1@lugnet.com...
> im trying to make a water floor for a boat model. does anyone have maybe a
> INC file, or tips on how to achieve this?
Here's the water from my "Titanic" rendering (Can be seen on Brickshelf
"Sinking ships", no URL available - I'm offline while writing). It combines
a 'plane with wawes' with a height field. The reason for the height field is
that a plane with wawes still is completely flat where the ship cuts the
water, while a height field gives more natural wawes, really sinking and
rising.
Experiment with the colors, transparency and scaling for the height field
(and plane) to get a sea you like. Do these experiments _without_ your
model, as it will take time enough anyway. Most of the color should come
from the plane, the heigh field is in fact in a dark gray, transparent
colour.
Beware: Transparent heightfields and radiosity renderings make for _VERY_
long rendering times. Don't try radiosity until you are completely happy
with the scene.
Something that is very difficult to generate is a wake after the ship, so
you'd better render a scene where it's natural for the ship to be still.
-----------------------------------------------------------
/* Water */
height_field {
tga "HeightField.tga" // Se further down how to make this one
smooth
pigment { color rgbt <0.1,0.1,0.1,0.6> }
finish {
ambient 0
diffuse .1
// crand 0.03
// specular 0.25
// roughness 1.8
reflection 0.5 //25
refraction 1
ior 1.3 //42
// caustics .9
}
rotate <180, 50, 0>
scale <5000, 100.0, 4000>
translate <100,-20,2800>
}
/**/
plane { y, 300.0
pigment {
Aquamarine /*DarkSlateBlue*/ }
normal {
waves 20
frequency 30
scale 3000.0
}
finish { ambient 0.5 specular 0.0 reflection 0.05 }
}
-----------------------------------------------------------
The HeightField.tga is produced with the following file, "HeightField.pov" -
make sure you set POVRay to generate a .tga file.
-----------------------------------------------------------
#include "colors.inc"
global_settings {
assumed_gamma 2.2
hf_gray_16
}
camera {
location <0, 0, -10>
look_at 0
}
plane { z, 10
pigment {
wrinkles
frequency 1
color_map {
[0 0.3*White]
[1 White]
}
}
}
light_source { <0, 20, -100> color White }
-----------------------------------------------------------
I couldn't find my 'Regina Maersk' .pov files, where the water colour is
much better :-(
As a side note, I've used the same height field to represent a snowy
landscape in one of my 'Christmas cards', and mountains (with other scaling
factors).
--
Anders Isaksson, Sweden
BlockCAD: http://user.tninet.se/~hbh828t/proglego.htm
Gallery: http://user.tninet.se/~hbh828t/gallery/index.htm
|
|
Message is in Reply To:
 | | water floor
|
| im trying to make a water floor for a boat model. does anyone have maybe a INC file, or tips on how to achieve this? (22 years ago, 8-Mar-03, to lugnet.cad.ray)
|
3 Messages in This Thread:
 
- Entire Thread on One Page:
- Nested:
All | Brief | Compact | Dots
Linear:
All | Brief | Compact
|
|
|
|
