Subject:
|
Re: Stickers for Tiles in POV
|
Newsgroups:
|
lugnet.cad.ray
|
Date:
|
Mon, 5 Jun 2000 16:39:51 GMT
|
Viewed:
|
722 times
|
| |
|
|
Brett Neale <brett_neale@bigpond.com> schrieb in im Newsbeitrag: FvoCpy.x6@lugnet.com...
> Hey guys
> How would I go about putting a .bmp or other image file into pov to put on a
> tile or brick? I am currently making a pov of the v8 supercar II 8448 and I
> need the tiles with the decorations on them that aren't in Ldraw. Thnx fellas
> Brett
Here's an excerpt from a rendering I did recently. The original POV file was
generated with L3P/L3PAO from an existing MPD file, then modified by hand.
I first declared the sticker as an object, so I could use it several times...
#declare US_flag = plane {
z, 0 // plane normal to z at the origin (xy plane)
texture {
pigment {
image_map {
gif "Us.gif" // insert your image here (can be gif, png, bmp, etc. just chaneg the keyword
interpolate 2 // smooth it a bit
once // do not repeat image across plane
}
// image is automatically scaled to x[0...1] y[x...1]
translate 0.5 * (-x + -y) // center on the origin, turn upside down, reverse left/right (you might not need this)
// you can remove the 0.5 factor if you don't want the origin at the center of the image
// don't forget to change the clipping box if you do
}
finish { ambient AMB diffuse DIF }
}
clipped_by {box {<-0.5, -0.5, -0.5> <0.5, 0.5, 0.5>}}
bounded_by {clipped_by}
}
Then I inserted the sticker into the appropriate submodel...
#declare flag_dot_dat = union {
// U.S. flag
object { _4095_dot_dat matrix <1-SW/12,0,0,0,1-SW/132,0,0,0,1-SW/12,0,SW/-2.44444,0> matrix <1,0,0,0,1,0,0,0,1,0,56,-50> #if
(version >= 3.1) material #else texture #end { Color366 } }
object { _2335_dot_dat matrix <1-SW/12,0,0,0,1-SW/40,0,0,0,1-SW/54,0,SW/2,SW/2.34783> matrix <1,0,0,0,1,0,0,0,1,0,-64,-50> #if
(version >= 3.1) material #else texture #end { Color7 } }
object { _3794_dot_dat matrix <1-SW/40,0,0,0,1-SW/12,0,0,0,1-SW/20,0,SW/6,0> matrix
<-0.707107,0,0.707107,0,1,0,-0.707107,0,-0.707107,0,68,-50> #if (version >= 3.1) material #else texture #end { Color8 } }
// US flag sticker for part 2335, one for every side
object { US_flag
scale <-40, -40, 1> // scale to appropriate size
rotate 90 * y // rotate to orientation of part 2335
translate <2, -44, -20> // translate to surface of part 2335 (origin at the center, so offset is -44,-20 instead of -64,0
// if you can't see the sticker in your rendering, you can let it float a bit above the surface
}
object { US_flag // ditto for back side
scale <-40, -40, 1>
rotate 90 * y
translate <-2, -44, -20>
}
}
I hope this helps (can find renderings from this POV file at
http://home.t-online.de/~axel.pq/msfc/recent.html)
Axel
02.06.2000 - William Jefferson Clinton receives the Karls-Prize
in Aachen, Germany, 50° 46' 17" N / 06° 05' 18" E
---------------------------------------------------------------
Axel Poque email: axel.pq@t-online.de
Aachen, Germany Internet: http://home.t-online.de/~axel.pq
|
|
Message has 1 Reply:
 | | Re: Stickers for Tiles in POV
|
| Good info. Thanks! I have two questions about this: 1. Is it possible to get a .gif to work with transparency? 2. I am not totally clear on how you flip an image end for end, or rotate it. Can you help me out? Thanks! Jake --- Jake McKee AFOL LUGNET (...) (23 years ago, 9-Nov-01, to lugnet.cad.ray)
|
Message is in Reply To:
| | Stickers for Tiles in POV
|
| Hey guys How would I go about putting a .bmp or other image file into pov to put on a tile or brick? I am currently making a pov of the v8 supercar II 8448 and I need the tiles with the decorations on them that aren't in Ldraw. Thnx fellas Brett (24 years ago, 5-Jun-00, to lugnet.cad.ray)
|
3 Messages in This Thread:
 
- Entire Thread on One Page:
- Nested:
All | Brief | Compact | Dots
Linear:
All | Brief | Compact
This Message and its Replies on One Page:
- Nested:
All | Brief | Compact | Dots
Linear:
All | Brief | Compact
|
|
|
|
